There is the Repeat Attributes button on the bottom of forms during the collection process, not the creating a form part, (Icon with a green arrow that points to the right), that if you select and fill out a form, it will keep all that same information and then next time you capture data and it opens the form it has all the previously entered data. That would do it for all pages though. So they would have to remove and change/edit everything on that second page. To do it for only one page, I think you are going to have to do the scripting with Global Variables like Rebecca Strauch said above.
There are "event scripts", but anything beyond quick quirps of code, you have to create a separate *.vbs file that compliments and is referred to in your form (*.apl). I, like Rebecca above started out with ArcPad 6 and so don't know much about AB, but will do my best to help you out. I was once just starting and trying to learn on my own and so hopefully this helps give you a starting position, as it sounds like you are interested in branching out, but have no idea how to get started. I am going to write this very basic in case that is the situation, if you are more advanced than just ignore the parts that you already know.
So, If you are looking at something as simple as: A person opens up ArcPad and collects their first data for the day and fills out the form and moves to the next. Upon collecting the next bit of data, the first page is filled out with exactly what was last written, but the second page is blank. Here is what you will need to do.
Create a .vbs file in the same directory as your .apl that has the same name as the .apl (i.e. If Tracker is hte name of your apl, you would do this: Tracker.apl & Tracker.vbs). A very simple way to do this is to copy a previous .vbs file there and rename it or create a blank Notepad file and change the name as well as the extension (New Notepad Document.txt to Tracker.vbs). Either way, once done, use Arcpad Studio to open the .vbs file. Make sure everything is cleared out and that is blank and then copy and paste the following into it:
Option Explicit
'setting program Variables
Dim OnOff
'On means to now load what was last typed in last.
'Since the first time it loads there is no Variables it is set to off, as soon as the
'first form is filled out, it is then turned on
Sub LayerOpen()
OnOff = 0 'Upon first load of the whole Layer, set OnOff to Off
End Sub
Sub Pressing_Ok()
' get page 1 controls
Dim pControls
Set pControls = ThisEvent.Object.Pages(1).Controls
' store the form data into a Global Variable.
'Replace the Names "txtStationID" with the ones that match your actual Names on your form.
Application.UserProperties("VarStationID") = pControls("txtStationID").Value
Application.UserProperties("VarProject") = pControls("cboProject").Value
Application.UserProperties("VarStationType") = pControls("txtStationType").Value
Application.UserProperties("VarTenement") = pControls("cboTenement").Value
'DATE:This style doesn't work with Date, so it is not included
Application.UserProperties("VarLogged_by") = pControls("cboLogged_by").Value
Application.UserProperties("VarRock_Code") = pControls("cboRock_Code").Value
Application.UserProperties("VarLith_desc") = pControls("txtLith_desc").Value
' clean up
Set pControls = Nothing
OnOff = 1
End Sub
Sub FormInit()
If OnOff = 1 then
' get page 1 controls
Dim pControls
Set pControls = ThisEvent.Object.Pages(1).Controls
'Set the form data to what is stored in the Global Variables
'Replace the Names "txtStationID" with the ones that match your actual Names on your form.
pControls("txtStationID").Value = Application.UserProperties("VarStationID")
pControls("cboProject").Value = Application.UserProperties("VarProject")
pControls("txtStationType").Value = Application.UserProperties("VarStationType")
pControls("cboTenement").Value = Application.UserProperties("VarTenement")
'This style doesn't work with Date, so it is not included
pControls("cboLogged_by").Value = Application.UserProperties("VarLogged_by")
pControls("cboRock_Code").Value = Application.UserProperties("VarRock_Code")
pControls("txtLith_desc").Value = Application.UserProperties("VarLith_desc")
' clean up
Set pControls = Nothing
End if
End Sub
Read through the code and Rem'd notes (Those just after an apostrophe) as there are some places you will need to make some changes to the code to make it work with your program. I tried to document it fairly well so that you can make changes as needed and get an idea on how it works so that you can have an idea for the next time.
Now back in your .apl, you will have to make a few changes on those event scripts on certain parts of it. Open the portion for the layer and set the onopen event to "Call LayerOpen()" without the quotes. What this is doing is saying upon this event, call upon the sub-routine in the .vbs file. If you look above in the code, you will see there is a "Sub LayerOpen()" and then sometime after that is an "End Sub". Everything between that is a sub-routine. So when that sub-routine is called, it runs everything within that routine. OK, two more. Now open the form and set onload to "Call FormInit()" without quotes and also set onok to "Call Pressing_ok()".
Ok, so now your apl know it needs to call those sub-routines, but needs to know what file to find those in. Since I have no idea how to do this except besides code, you will have to do this last part via that way. On your toolbar in ArcPad studio with the apl open, there will be a button that has to arrows pointing away from each other one a top the other. One is blue and one is red. The tooltip on it says "Toggle between source and treeview". Click that button and it will probably ask you to save and of course say yes. You will now be looking at the code. Without changing anything, go to the very bottom and right above where it says "</ArcPad>" type "<SCRIPT src="Tracker.vbs" language="vbscript"/>" without the first and last quote. Make sure to change the actual "Tracker.vbs" to whatever the name of your .vbs file is. Esentially, it should look something like this at the end:
</LAYER>
<SCRIPT src="Tracker.vbs" language="vbscript"/>
</ArcPad>
Go ahead and hit that toggle between source and treeview button again. Tell it yes you want to save and then you should be in business.
As for the date field, since it can't be handed in this same manner, if it is just for today's date you are looking for anyway, set that text fields default value to "Now" without quotes.
Good luck and let me know how it works out.