ArcMap Basic Standard Professional Startup Script

Document created by curtvprice Champion on Aug 30, 2017Last modified by curtvprice Champion on May 13, 2018
Version 5Show Document
  • View in full screen mode

This .bat script launches a ArcGIS Desktop app using the specified license level. The script assumes that the desktop is set up for concurrent use, not single use licensing.

 

To use the script, edit and save the code to a text file and rename with a .bat extension. Users can run the .bat file with a double-click from Windows Explorer (it will then start up the app with default settings), or you could setup a shortcut that provides the command line arguments as they need.

 

The nice thing about this script is it does not require the user to alter any global environment variables or run anything that requires elevated privileges.

 

This script may be useful for organizations with a limited number of Standard (ArcEditor) or Professional (ArcInfo) licenses. Users could be set up with an Viewer (ArcView) license and instructed to start up desktop using an elevated license level when needed. The next time they launch ArcGIS Desktop in the normal way, it will be using their installed setup.

 

:: save this file as arcz.bat
:: usage: arcz {VIEWER|EDITOR|PROFESSIONAL} {ARCMAP|ARCCATALOG|ARCSCENE|ARCGLOBE}  {server}
@echo off
setlocal
set class=%1
set app=%2
set server=%3

:: edit below to set defaults if not provided
set deflevel=PROFESSIONAL
set defapp=ARCMAP
set defserver=27004@your_default_server
:: do not edit below this line
if "%class%"=="" set class=%deflevel%
if "%class%"=="#" set class=%deflevel%
if "%app%"=="" set app=%defapp%
if "%app%"=="#" set app=%defapp%
if "%server%"=="" set server=%defserver%


:: set up environment and launch application
set ARCGIS_LICENSE_FILE=%server%
set ESRI_SOFTWARE_CLASS=%class%

:: report values
set ARCGIS_LICENSE_FILE
set ESRI_SOFTWARE_CLASS
echo Starting %app%.exe ...
start /d "%AGSDESKTOPJAVA%bin" /b %app%.exe
pause

 

How To: Change the ArcGIS Desktop seat type for Citrix or restricted permissions environments 

ArcGIS 10.1 Licensing in a restricted environment. | Esri Australia Technical Blog 

Change ArcGIS Desktop license level and LM machines w/o Admin rights 10/11/2017

Attachments

    Outcomes