How to select multiple feature using VBA ?

StutiChandel

Hi,

I am a little new to this but I wanted to know how do I select multiple features in a layer using VBA? I would appretiate if I could get some code. for eg selecting two or more point features.

Thanks,
Stuti Chandel

PhilMiotto

Both of these VBA samples will select multiple features in the map.


To perform a spatial  selection - "select within":

Sub SpatialSelection()
  Dim pMxApp As IMxApplication
  Dim pMxDoc As IMxDocument
  Dim pMap As IMap
  Dim pTargetLayer As IFeatureLayer
  Dim pSelectingLayer As IFeatureLayer
  Dim pFeatureClass As IFeatureClass
  Dim pEnvelope As IEnvelope
  Dim pFeatureSelection As IFeatureSelection
  Dim pSpatialFilter As ISpatialFilter
  
  Set pMxApp = Application
  Set pMxDoc = Application.Document
  Set pMap = pMxDoc.FocusMap

  Set pTargetLayer = pMap.Layer(0)
  Set pSelectingLayer = pMap.Layer(1)
  Set pFeatureClass = pTargetLayer.FeatureClass
  Set pEnvelope = pSelectingLayer.AreaOfInterest
  
  Set pFeatureSelection = pTargetLayer
  Set pSpatialFilter = New SpatialFilter
  With pSpatialFilter
    Set .Geometry = pEnvelope
    .GeometryField = pFeatureClass.ShapeFieldName
    .SpatialRel = esriSpatialRelContains
    'add an optional .WhereClause
  End With
  
  pFeatureSelection.SelectFeatures pSpatialFilter, esriSelectionResultNew, False
  pMxDoc.ActiveView.PartialRefresh esriViewGeoSelection, Nothing, Nothing
End Sub

To perform a selection of features within a graphic drawn in the map - this is MouseDown code for a UIToolControl, which will allow you to draw the graphic then selects the features within that graphic:

Private Sub UIToolControl1_MouseDown(ByVal button As Long, ByVal shift As Long, ByVal x As Long, ByVal y As Long)
    Dim pMxApp        As IMxApplication
    Dim pMxDoc        As IMxDocument
    Dim pMap          As IMap
    Dim pActiveView   As IActiveView
    Dim pRubberBand   As IRubberBand
    Dim pSelectionSet As ISelectionSet
    Dim pFeatureLayer As IFeatureLayer2
    Dim pFeatureSelection As IFeatureSelection
    Dim pTargetLayer As IFeatureLayer
    Dim pCircleArc As ICircularArc
    Dim pSegColl As ISegmentCollection
    Dim pFLayer As IFeatureLayer
    Dim pFc As IFeatureClass
    Dim pPoly As IPolygon
    
    Set pMxApp = Application
    Set pMxDoc = ThisDocument
    Set pMap = pMxDoc.FocusMap
    Set pActiveView = pMap
    Set pTargetLayer = pMap.Layer(0)
    Set pRubberBand = New RubberCircle
    Set pCircleArc = pRubberBand.TrackNew(pActiveView.ScreenDisplay, Nothing)
    Set pSegColl = New Polygon
    pSegColl.SetCircle pCircleArc.CenterPoint, pCircleArc.Radius
    Set pFLayer = pMap.Layer(0)
    Set pFc = pFLayer.FeatureClass
    Set pPoly = pSegColl
    
    
    Dim pSF As ISpatialFilter
    Set pSF = New SpatialFilter
    With pSF
        Set .Geometry = pPoly
        .GeometryField = pTargetLayer.FeatureClass.ShapeFieldName
        .SpatialRel = esriSpatialRelIntersects
    End With
    
    Set pFeatureSelection = pTargetLayer
    pFeatureSelection.SelectFeatures pSF, esriSelectionResultNew, False
    pMxDoc.ActiveView.Refresh

End Sub