Field Calculation rules for date entry

CodyYager

Hi,

I am trying to create some attribute rules to work with our Cartegraph instance so we can keep track of data that has been retired by our Public Works crews. I have created two simple expressions to calculate a date field and to alter a lifecycle field, but they will not allow me to manually populate the date field and retire a feature. 

 

Here are the two expressions, the first calculates the date for a feature thats lifecycle is not asbuilt or unknown. The second is supposed to calculate the lifecycle as abandoned if there is a date in the CarteRetire field. I assume the majority of the problem lies in the second expression; I am not very good at scripting yet. Both of these are set to trigger on updates only.

if ($feature.LIFECYCLE == "ASBUILT,UNKNOWN" || $feature.LIFECYCLE == $originalfeature.LIFECYCLE){
return NULL
} else {
return Date()
}

 

if (IsEmpty($feature.CarteRetire))
return $feature.LIFECYCLE
else {
return "ABANDONED"
}

 

2023-05-24_13-33-09.png

2023-05-24_13-32-36.png

JohannesLindner

The behavior you want isn't that simple...

Your two rules influence each other. The first rule looks at the field that gets changed by the second rule and vice versa. It might be better to do it in one rule:

 

// Calculation Attribute RUle
// field: empty!
// triggers: update

var lifecycle = $feature.TextField1
var old_lifecycle = $originalfeature.TextField1
var retire_date = $feature.DateField1
var old_retire_date = $originalfeature.DateField1


// Was the date changed to a non-null value?
var abandon_feature = retire_date != null && retire_date != old_retire_date

// Was the lifecycle changed to "ABANDONED"?
var feature_was_abandoned = lifecycle == "ABANDONED" && lifecycle != old_lifecycle

// Calculate the new values
var new_retire_date = When(
    abandon_feature, retire_date,      // the date was changed by the user, use that value
    feature_was_abandoned, Date(),     // the lifecycle was changed to "ABANDONED", use current date
    lifecycle != "ABANDONED", null,    // the feature is not abandoned, set the date to null
    retire_date                        // the feature is abandoned, some other field was updated, use existing value
)
var new_lifecycle = IIf(
    abandon_feature, "ABANDONED",    // the date was changed by the user, abandon the feature
    lifecycle                        // some other field was updated, use the existing value
)

return {
    result: {attributes: {
        DateField1: new_retire_date,
        TextField1: new_lifecycle
    }}
}

 

Change the field names in lines 5-8 and 31-32.