attribute data to related record from parent feature using arcade

AdejumoBidemi

Hi everyone, 

I'm trying to use arcade to pull the address from 3 features. I want to pull the address into the related table iterating through the 3 features and pulling the first one found. The address will be pulled based on the global ID

Code:

Spoiler

//create featuresSets for each Layer in the service
var p1 = FeatureSetByName($map,"parcel (LogTest )")
var p2 = FeatureSetByName($map,"building (LogTest )")
var p3 = FeatureSetByName($map,"facilities (LogTest)")

//Filter your FeatureSets by Site ID
var GUID = $feature.GLOBALID
var p1_filter = Filter(p1, "GUID = @$feature.GLOBALID")
var p2_filter = Filter(p2, "GUID = @$feature.GLOBALID")
var p3_filter = Filter(p3, "GUID = @$feature.GLOBALID")

//Return the address of the parent feature
if(Count(p1_filter) > 0) {
return First(p2_filter).Address
}
else if(Count(p2_filter) > 0) {
return First(p3_filter).Address
}
else if(Count(p3_filter) > 0) {
return First(p3_filter).Address
}

else{
return null;
}

 

JohannesLindner

• You need to use a variable with the @ notation in the Filter() function. You already created that variable, but then you try to use $feature in the sql statement, which doesn't work.
• You're trying to return from the wrong featuresets for p1 and p2.
• It should be faster to do the loading, filtering and returning for each layer before going to the next layer. This way, you don't unneccessarily load data.
• You don't need all those else's. If you return from a function, everything after that return statement isn't executed anymore.

 

var GUID = $feature.GLOBALID

var p1 = FeatureSetByName($map,"parcel (LogTest )")
var p1_filter = Filter(p1, "GUID = @GUID")
if(Count(p1_filter) > 0) {
    return First(p1_filter).Address
}

var p2 = FeatureSetByName($map,"building (LogTest )")
var p2_filter = Filter(p2, "GUID = @GUID")
if(Count(p2_filter) > 0) {
    return First(p2_filter).Address
}

var p3 = FeatureSetByName($map,"facilities (LogTest)")
var p3_filter = Filter(p3, "GUID = @GUID")
if(Count(p3_filter) > 0) {
    return First(p3_filter).Address
}

return null