topic Re: Clear controls on Tabs in ArcPad Questions

Clear controls on Tabs

JayKappy — Fri, 06 May 2011 12:55:38 GMT

In my app the user clicks on an existing feature. it asks them to create a historical record, if yes it runs some SQL statement that updates a related table. After the save (which works fine) I am trying to clear/set the existing controls on the 3 tabs in the form to either 0, none, NA.
I am using the below code and for the most part it is working...I can modify the values on TAB 1, but for some reason the controls on TAB 2 and TAB 3 are not being effected?

Anyone know why?

THanks

Sub ClearForms

 Dim objRS1, objEditForm1, objSelLayer1
 Set objSelLayer1 = Map.SelectionLayer
 Set objRS1 = objSelLayer1.Records
 objRS1.Bookmark = Map.SelectionBookmark

 ' Clear Page 1
 Dim objEFPageOneControls1
 Set objEditForm1 = application.map.layers("Outfalls").forms("EDITFORM")
 Set objEFPageOneControls1 = objEditForm1.Pages("page1").Controls
  objEFPageOneControls1("txtSEDDIST_FT").Value = "0"
  objEFPageOneControls1("txtSEDLGTH_FT").Value = "0"
  objEFPageOneControls1("txtSEDWDTH_FT").Value = "0"
  objEFPageOneControls1("txtOFWTRHT_IN").Value = "0"

 ' Clear Page 2
 Dim objEFPageOneControls2
 Set objEFPageOneControls2 = objEditForm1.Pages("page2").Controls
  objEFPageOneControls2("txtCOMMENTS").Value = "none"
  objEFPageOneControls2("Edit1").Value = "none"
  objEFPageOneControls2("Edit2").Value = "none"

 ' Clear Page 3
 Dim objEFPageOneControls3
 Set objEFPageOneControls3 = objEditForm1.Pages("page3").Controls
  objEFPageOneControls3("image1").Value = "none"
  objEFPageOneControls3("image2").Value = "none"
  objEFPageOneControls3("image3").Value = "none"
End Sub

Re: Clear controls on Tabs

JayKappy — Sat, 11 Dec 2021 14:24:04 GMT

This is driving me nuts...why cant I set the controls on the 2nd and 3rd tabs?

THanks

Funny thing is that I can disable the controls the same way....

Sub DisableTab1and2

 Dim objRS6, objEFPageOneControls6, objEditForm6, objSelLayer6
 Set objSelLayer6 = Map.SelectionLayer
 Set objRS6 = objSelLayer6.Records
 objRS6.Bookmark = Map.SelectionBookmark

 Set objEditForm6 = application.map.layers("Outfalls").forms("EDITFORM")
 Set objEFPageOneControls6 = objEditForm6.Pages("page1").Controls
 objEFPageOneControls6("cbo_User").Enabled = False
 objEFPageOneControls6("txtUniqueID").Enabled = False
 objEFPageOneControls6("Edit1").Enabled = False
 objEFPageOneControls6("Edit9").Enabled = False
 objEFPageOneControls6("txtSEDDIST_FT").Enabled = False
 objEFPageOneControls6("txtSEDLGTH_FT").Enabled = False
 objEFPageOneControls6("txtSEDWDTH_FT").Enabled = False
 objEFPageOneControls6("txtOFWTRHT_IN").Enabled = False

 Dim objEFPageOneControls12
 Set objEFPageOneControls12 = objEditForm6.Pages("page2").Controls
 objEFPageOneControls12("txtCOMMENTS").Enabled = False
 objEFPageOneControls12("Edit1").Enabled = False
 objEFPageOneControls12("Edit2").Enabled = False

 Dim objEFPageOneControls3
 Set objEFPageOneControls3 = objEditForm6.Pages("page3").Controls
 objEFPageOneControls3("image1").Enabled = False
 objEFPageOneControls3("image2").Enabled = False
 objEFPageOneControls3("image3").Enabled = False
End Sub

Re: Clear controls on Tabs

RolfBroch — Wed, 11 May 2011 06:52:46 GMT

In order to change a value/text on a control on a page the page in question MUST be the active page. You can change the property of a control (enable, disable etc..) without the page beeing active but not the value/text of the control.

Rolf

Re: Clear controls on Tabs

JayKappy — Wed, 11 May 2011 12:23:25 GMT

Can I make the page active programmatically?
And then clear the controls...sort of wipe the form

Re: Clear controls on Tabs

RolfBroch — Wed, 11 May 2011 13:29:49 GMT

Something like this:

Sub ClearForms

Dim objRS1, objEditForm1, objSelLayer1
Set objSelLayer1 = Map.SelectionLayer
Set objRS1 = objSelLayer1.Records
objRS1.Bookmark = Map.SelectionBookmark

Dim pPage

' Clear Page 1
Dim objEFPageOneControls1
Dim pFirstPage
Set objEditForm1 = application.map.layers("Outfalls").forms("EDITFORM")
Set pFirstPage = objEditForm1.Pages("page1")
pFirstPage.Activate
Set objEFPageOneControls1 = objEditForm1.Pages("page1").Controls
objEFPageOneControls1("txtSEDDIST_FT").Value = "0"
objEFPageOneControls1("txtSEDLGTH_FT").Value = "0"
objEFPageOneControls1("txtSEDWDTH_FT").Value = "0"
objEFPageOneControls1("txtOFWTRHT_IN").Value = "0"

' Clear Page 2
Dim objEFPageOneControls2
Set pPage = objEditForm1.Pages("page2")
pPage.Activate
Set objEFPageOneControls2 = objEditForm1.Pages("page2").Controls
objEFPageOneControls2("txtCOMMENTS").Value = "none"
objEFPageOneControls2("Edit1").Value = "none"
objEFPageOneControls2("Edit2").Value = "none"

' Clear Page 3
Dim objEFPageOneControls3
Set pPage = objEditForm1.Pages("page3")
pPage.Activate
Set objEFPageOneControls3 = objEditForm1.Pages("page3").Controls
objEFPageOneControls3("image1").Value = "none"
objEFPageOneControls3("image2").Value = "none"
objEFPageOneControls3("image3").Value = "none"
pFirstPage.Activate
End Sub

Here is a function I use quite frequently. It will clear comboboxes (but keep the drop down values), empty text controls, set date controls to todays date and clear checkboxes on all pages for the form being passed to the function.

Function ClearValues(byRef frm)
Dim pControl, pPage
For Each pPage In frm.Pages
    pPage.Activate

    For Each pControl In pPage.Controls
      Select Case pControl.Type
        Case "COMBOBOX"
          If pControl.ListCount = 1 Then
            pControl.ListIndex = 0
          Else
            pControl.ListIndex = -1
          End If

        Case "DATETIME"
          pControl.Value = Now

        Case "EDIT"
          pControl.Value = ""

        Case "CHECKBOX"
          pControl.Value = 0 'False
      End Select
    Next
Next

frm.Pages(1).Activate

' CleanUp
Set pControl = Nothing
Set pPage = Nothing
End Function

Re: Clear controls on Tabs

JayKappy — Wed, 11 May 2011 14:49:53 GMT

AWESOME....THANKS MAN....

How would I call the fnuction from the code..... just call this function from here?
I am a bit confused how to call an dinteact with the function.....from what I see all I have to do is fire the function off and it will walk thorough the pages and set them....and then return to the first page...
Just cant figure out how to call it....Functions confuse the heck out of me....I dont understand what I am passing from the call to the function and back

Dim YesOrNoAnswerToMessageBox
Dim QuestionToMessageBox

QuestionToMessageBox = "Do you want to enter new data?" & VBNewline & VBNewline & "Are you sure you want to create the historical record now"

YesOrNoAnswerToMessageBox = MsgBox(QuestionToMessageBox, vbYesNo, "VBA Expert or Not")

If YesOrNoAnswerToMessageBox = vbNo Then
Exit Sub
Else
' CLear all the Textboxes and Comboboxes, comments, images and video
'Call ClearForms
CALL THE FUNCTION

End If

Re: Clear controls on Tabs

RolfBroch — Wed, 11 May 2011 18:03:53 GMT

As long as you have the form object you can call it like this

Set pForm = Application.Map.Layers("Outfalls").Forms("EDITFORM")
ClearValues pForm

Re: Clear controls on Tabs

JayKappy — Wed, 11 May 2011 18:32:29 GMT

Thanks again...was able to make that work...
Although in my application I have a couple textboxes on the form that cannot be changed...The contain Unique Ids etc. So I have to do it the original way I was trying...which is also working

BUT your function will come in very handy on other projects....I thank you for your time, patience and examples....

THanks again....

Re: Clear controls on Tabs

RolfBroch — Wed, 11 May 2011 18:51:13 GMT

If you for example has an edit control that you want to skip add this statement under the case statement for the edit control

Case "EDIT"
If pControl.Name <> "theNameOfYourControl" Then
pControl.Value = ""
End If

and if there are more EditControls just add them like this
Case "EDIT"
If pControl.Name <> "theNameOfYourControl" and
pControl.Name <> "theNameOfAnotherControl" Then
pControl.Value = ""
End If

Re: Clear controls on Tabs

JayKappy — Sat, 11 Dec 2021 14:24:07 GMT

I am getting a syntax error with this....anything you can see? Edit1 and Edit2 are on the first tab...I dont think this error is arising because Edit1 and Edit2 are not on pages 2 and 3....?

Microsoft VBScript error
Syntax error
Source Text Unavailable

Case "EDIT"
If pControl.Name <> "Edit1" and
     pControl.Name <> "Edit2" Then
     pControl.Value = ""
End If

Re: Clear controls on Tabs

RolfBroch — Thu, 12 May 2011 07:45:32 GMT

Oops forgot the _ as in

If pControl.Name <> "Edit1" and _
pControl.Name <> "Edit2" Then
pControl.Value = ""
End If

The _ is a line continuation character

Re: Clear controls on Tabs

JayKappy — Sun, 12 Dec 2021 16:18:46 GMT

WORKS like a charm......thanks Rolf for your time, patience and examples....
Very appreciated....

My Final Code

Sub ExistingRecord

 Dim objRS6, objEFPageOneControls6, objEditForm6, objSelLayer6
 Set objSelLayer6 = Map.SelectionLayer
 Set objRS6 = objSelLayer6.Records

 objRS6.Bookmark = Map.SelectionBookmark
 Set objEditForm6 = application.map.layers("Outfalls").forms("EDITFORM")
 Set objEFPageOneControls6 = objEditForm6.Pages("page1").Controls

 ' Give the user option to add new record on existing feature
 Dim YesOrNoAnswerToMessageBox
 Dim QuestionToMessageBox

 QuestionToMessageBox = "Do you want to enter new data?" & VBNewline & VBNewline & "Are you sure you want to create the historical record now"

 YesOrNoAnswerToMessageBox = MsgBox(QuestionToMessageBox, vbYesNo, "VBA Expert or Not")

 If YesOrNoAnswerToMessageBox = vbNo Then

 ' enable the Button to allow the user to create the historical record Onclick
 Call EnableButton
       
 Else
 '' CALL the function below to clear the form controls.
 Set objEditForm6 = Application.Map.Layers("Outfalls").Forms("EDITFORM")
 ClearValues objEditForm6 
 End If

End Sub


Function ClearValues(byRef frm)
' This function activates each page and clears/sets the control values 

 Dim pControl, pPage

 For Each pPage In frm.Pages
 pPage.Activate
  For Each pControl In pPage.Controls
   Select Case pControl.Type
    Case "COMBOBOX"
    If pControl.ListCount = 1 Then
    pControl.ListIndex = 0
    Else
    pControl.ListIndex = -1
    End If

    Case "DOMAINFIELD"
    If pControl.Name = "Field1" Then
     pControl.Value = "NA"
    Elseif pControl.Name = "Field2" Then
     pControl.Value = "None"
    Elseif pControl.Name = "Field3" Then
     pControl.Value = "No"
    Elseif pControl.Name = "Field4" Then
     pControl.Value = "None"
    Elseif pControl.Name = "Field5" Then
     pControl.Value = "None"
    Else
    End If 

    Case "DATETIME"
    pControl.Value = Now

    'Case "EDIT"

    Case "EDIT"
    If pControl.Name <> "cbo_User" and _
     pControl.Name <> "txtUniqueID" and _
     pControl.Name <> "Edit1" and _
        pControl.Name <> "Edit9" Then
     pControl.Value = "none"
    End If 

    Case "CHECKBOX"
    pControl.Value = 0 'False
   End Select
  Next
 Next

 frm.Pages(1).Activate

 ' CleanUp
 Set pControl = Nothing
 Set pPage = Nothing

End Function

Re: Clear controls on Tabs

JayKappy — Thu, 12 May 2011 15:37:42 GMT

Thanks Rolf

Re: Clear controls on Tabs

RolfBroch — Fri, 13 May 2011 08:53:08 GMT

Happy I could help out.

The power of ArcPad is great. With a little bit of code you can get ArcPad to do stuff you need an ArcInfo license of ArcGIS Desktop to do.

Rolf