topic Change Point Symbol in ArcGIS Viewer for Flex Questions

Change Point Symbol

YanuardiHerdiyono — Thu, 21 Feb 2013 05:55:25 GMT

Hello All,

I have add georss layer (http://earthquake.usgs.gov/earthquakes/feed/atom/1.0/week) to my operational layer. How to change point symbol on georss layer type?

Re: Change Point Symbol

RobertScheitlin__GISP — Sun, 12 Dec 2021 02:51:21 GMT

Yanuardi,

GeoRSSLayers can be tricky as they can have multiple geometry types but here is a way based on the fact that the GeoRSS feed you are using is a point type geometry.

You need to specify the renderer in the Main config.xml:

            <layer label="Earthquakes GeoRSS" type="georss" visible="true" alpha="1"
                url="http://earthquake.usgs.gov/earthquakes/feed/atom/1.0/week">
                <simplerenderer>
                    <simplemarkersymbol style="diamond" size="12" color="0xff0000" alpha="1" />
                </simplerenderer>
            </layer>

And Unfortunately you will have to modify the viewers source code to use the renderer for the GeoRSSLayer. In the src\com\esri\viewer\managers\LayerCreator.as file:

    private static function createGeoRSSLayer(layerCreationProperties:LayerCreationProperties):GeoRSSLayer
    {
        var geoRSSLayer:GeoRSSLayer = new GeoRSSLayer(layerCreationProperties.url);

        geoRSSLayer.alpha = layerCreationProperties.alpha;
        geoRSSLayer.id = layerCreationProperties.label;
        geoRSSLayer.name = layerCreationProperties.label;
        geoRSSLayer.disableClientCaching = layerCreationProperties.disableClientCaching;
        if (layerCreationProperties.renderer)
        {
            geoRSSLayer.addEventListener(LayerEvent.LOAD,function loadSymbol(event:LayerEvent):void{
                FeatureLayer(geoRSSLayer.featureLayers[0]).renderer = layerCreationProperties.renderer;
            });
        }
        if (layerCreationProperties.serviceURL)
        {
            geoRSSLayer.serviceURL = layerCreationProperties.serviceURL;
        }
        if (!isNaN(layerCreationProperties.minScale))
        {
            geoRSSLayer.minScale = layerCreationProperties.minScale;
        }
        if (!isNaN(layerCreationProperties.maxScale))
        {
            geoRSSLayer.maxScale = layerCreationProperties.maxScale;
        }
        geoRSSLayer.visible = layerCreationProperties.visible;
        return geoRSSLayer;
    }

Don't forget to click the Mark as answer check on this post and to click the top arrow (promote).
Follow these steps as shown in the below graphic:

Re: Change Point Symbol

YanuardiHerdiyono — Fri, 22 Feb 2013 00:08:39 GMT

Thanks Robert for your answerd , it means I have to recompile source code using adobe builder?

Re: Change Point Symbol

RobertScheitlin__GISP — Fri, 22 Feb 2013 02:09:15 GMT

Yanuardi,

Unfortunately yes it will require recompiling the viewer as the GeoRSSLayer currently is not configured to handle the renderer tag in the main config.xml like other layer types.

Re: Change Point Symbol

KennethLyons — Thu, 12 Dec 2013 15:09:43 GMT

I'm attempting to do something similar to a GeoRSS feed that I'm working with. The difference with mine is that I'm attempting to use the UniqueValueRenderer because there are a large number of values that can be used to identify symbols. I've been successful using this function in the past on published services, however I'm not having any luck using it with a GeoRSS feed. I believe that my issue is that I don't know the name of the field that the values would come from, but I am unsure.

Should the UniqueValueRenderer work correctly with a GeoRSS feed or am I wasting my time working on this solution.

Thanks

Re: Change Point Symbol

RobertScheitlin__GISP — Thu, 12 Dec 2013 15:17:53 GMT

Kenneth,

To my knowledege a unique value rendereer on a GeoRSSLayer should work fine.

Re: Change Point Symbol

KennethLyons — Thu, 12 Dec 2013 15:26:33 GMT

R,

I'm working with Flex 3.4, will I need to make the changes to the LayerCreater.as you suggested in the previous posts in order for it to work correctly?

Thanks

Re: Change Point Symbol

RobertScheitlin__GISP — Thu, 12 Dec 2013 15:32:17 GMT

Kenneth,

Nope it looks like it made it into 3.4.

Let me retract that...
Individual symbology made it into 3.2 of the viewer for GeoRSS

setting the renderer did not. So you you will have to add it.

Re: Change Point Symbol

KennethLyons — Sun, 12 Dec 2021 02:51:23 GMT

I'm recieving errpr 1046: Type wasnot found or was not a compile-time constant: LayerEvent
Do I need to add a line to the "import" secton at the beginning of the .as?

Here is what I have I copied it straight from your previous post:

 private static function createGeoRSSLayer(layerCreationProperties:LayerCreationProperties):GeoRSSLayer
    {
        var geoRSSLayer:GeoRSSLayer = new GeoRSSLayer(layerCreationProperties.url);

        geoRSSLayer.alpha = layerCreationProperties.alpha;
        geoRSSLayer.id = layerCreationProperties.label;
        geoRSSLayer.name = layerCreationProperties.label;
        geoRSSLayer.disableClientCaching = layerCreationProperties.disableClientCaching;
        geoRSSLayer.showInLegend = layerCreationProperties.showInLegend;
        geoRSSLayer.visible = layerCreationProperties.visible;
  
  if (layerCreationProperties.renderer)
  {
   geoRSSLayer.addEventListener(LayerEvent.LOAD,function loadSymbol(event:LayerEvent):void{FeatureLayer(geoRSSLayer.featureLayers[0]).renderer = layerCreationProperties.renderer;});
  }

        if (layerCreationProperties.copyright != null)
        {
            geoRSSLayer.copyright = layerCreationProperties.copyright;
        }
        if (layerCreationProperties.serviceURL)
        {
            geoRSSLayer.serviceURL = layerCreationProperties.serviceURL;
        }
        if (!isNaN(layerCreationProperties.minScale))
        {
            geoRSSLayer.minScale = layerCreationProperties.minScale;
        }
        if (!isNaN(layerCreationProperties.maxScale))
        {
            geoRSSLayer.maxScale = layerCreationProperties.maxScale;
        }
        if (layerCreationProperties.markerSymbol)
        {
            geoRSSLayer.pointSymbol = layerCreationProperties.markerSymbol;
        }
        if (layerCreationProperties.lineSymbol)
        {
            geoRSSLayer.polylineSymbol = layerCreationProperties.lineSymbol;
        }
        if (layerCreationProperties.fillSymbol)
        {
            geoRSSLayer.polygonSymbol = layerCreationProperties.fillSymbol;
        }

        return geoRSSLayer;
    }

Thanks again

Re: Change Point Symbol

RobertScheitlin__GISP — Fri, 13 Dec 2013 02:32:49 GMT

Kenneth,

Yes add

import com.esri.ags.events.LayerEvent;

Re: Change Point Symbol

KennethLyons — Fri, 13 Dec 2013 13:39:54 GMT

That cleared up the error. Thanks to the assistance. It's still not changing my symbololgy, but I think I still need to do a litte research.

Thanks again