topic Re: cost matrix in ArcGIS Network Analyst Questions

cost matrix

FelipeLillo — Mon, 13 Sep 2010 01:12:18 GMT

Hi there,

I have a network dataset which represents roads and a shapefile with cities ....what I wanna do is to generate a cost matrix that contains the distance between two connected cities in the network. For this case the OD_matrix_solver is not desired because it calculates shortest distances between cities.... all I want is the "link_length" between cities..... I've been looking some scripts but most of them just compute euclidean distances between connected points..the question is how I can do the same but using the real shape.

I imagine that analogously to OD_matrix_solver...first I'd have to snap locations to my road network and next to generate the matrix.

Can anyone give me a little help here???...thanks

Re: cost matrix

JaySandhu — Mon, 13 Sep 2010 14:12:42 GMT

You start of by saying that you want the distance between two cities and then it is not clear from your post what you need to generate. Can you elaborate on what is "link length" as opposed to "shortest distance" that the OD Cost Matrix generates? OD Cost matrix generates the shortest path distance (route over the network) between the sets of origins and destinations. Not sure what other distance you need. Please elaborate.
Jay Sandhu

Re: cost matrix

FelipeLillo — Mon, 13 Sep 2010 21:32:18 GMT

To make it clearer, you have your network with edges and vertices(cities)... each edge (or link connecting two vertices) has a weight associated (in this case distance "d")....I wanna extract the weight of each link from my map and put them in a matrix like (instead of "ones" I need distances):

Re: cost matrix

JaySandhu — Tue, 14 Sep 2010 13:49:34 GMT

Ok. What you want is the connectivity matrix of the network graph and the edge costs. You can generate that by using some VBA that I list below. To use this, add the network dataset to ArcMap. Make sure to change the name of the attribute name (in this case I have it as meters) to the one that is in your data. The run it in the VBA. The immedate window will show the results. You can re-format the debug.print lines (change them to write to a file) as needed. The output will currently look like this:

Junction: 1 is adjacent to: 1 junctions.
Adjacent Junction: 2 Length 235.7
Junction: 2 is adjacent to: 3 junctions.
Adjacent Junction: 1 Length 235.7
Adjacent Junction: 4 Length 470
Adjacent Junction: 6287 Length 287.8

Regards,
Jay Sandhu

Public Sub List_Adjacent_Junctions()
On Error GoTo eh

Dim pMxDoc As IMxDocument
Set pMxDoc = ThisDocument

Dim pNLayer As INetworkLayer
Set pNLayer = pMxDoc.FocusMap.Layer(0)

Dim pND As INetworkDataset
Set pND = pNLayer.NetworkDataset

Dim pNQ As INetworkQuery
Set pNQ = pND

Dim pEnumNE As IEnumNetworkElement
Set pEnumNE = pNQ.Elements(esriNETJunction)

Dim pNEdge As INetworkEdge
Set pNEdge = pNQ.CreateNetworkElement(esriNETEdge)
Dim pNEFromJunc As INetworkJunction
Set pNEFromJunc = pNQ.CreateNetworkElement(esriNETJunction)
Dim pNEToJunc As INetworkJunction
Set pNEToJunc = pNQ.CreateNetworkElement(esriNETJunction)

Dim pNE As INetworkElement
Set pNE = pEnumNE.Next

Dim pNEJunc As INetworkJunction
Set pNEJunc = pNE

Dim i As Integer
Do Until pNE Is Nothing
    Debug.Print "Junction: " & pNEJunc.EID & " is adjacent to: " & pNEJunc.EdgeCount & " junctions."
    For i = 0 To pNEJunc.EdgeCount - 1 'For each connected edge...
      pNEJunc.QueryEdge i, True, pNEdge   'Get that connected edge
      pNEdge.QueryJunctions pNEFromJunc, pNEToJunc 'Get To junction of current edge
      Debug.Print " Adjacent Junction: " & pNEToJunc.EID & " Length " & pNEdge.AttributeValueByName("Meters") 'List the adjacency
    Next
    Set pNE = pEnumNE.Next
Loop
Exit Sub
eh:
MsgBox "Error: " & Err.Description
End Sub

Re: cost matrix

FelipeLillo — Tue, 14 Sep 2010 21:23:49 GMT

Thanks very much Jay for you valuable help.

Regards

Philip

Re: cost matrix

FelipeLillo — Tue, 14 Sep 2010 22:20:50 GMT

Hi JAy ,

I've been trying to run the code, but my ArcGIS report an "Automation error"...but there is not specification what error is...no error number, nothing....any idea what problem might be??

THanks

Philip

Ok. What you want is the connectivity matrix of the network graph and the edge costs. You can generate that by using some VBA that I list below. To use this, add the network dataset to ArcMap. Make sure to change the name of the attribute name (in this case I have it as meters) to the one that is in your data. The run it in the VBA. The immedate window will show the results. You can re-format the debug.print lines (change them to write to a file) as needed. The output will currently look like this:

Junction: 1 is adjacent to: 1 junctions.
Adjacent Junction: 2 Length 235.7
Junction: 2 is adjacent to: 3 junctions.
Adjacent Junction: 1 Length 235.7
Adjacent Junction: 4 Length 470
Adjacent Junction: 6287 Length 287.8

Regards,
Jay Sandhu

Public Sub List_Adjacent_Junctions()
On Error GoTo eh

Dim pMxDoc As IMxDocument
Set pMxDoc = ThisDocument

Dim pNLayer As INetworkLayer
Set pNLayer = pMxDoc.FocusMap.Layer(0)

Dim pND As INetworkDataset
Set pND = pNLayer.NetworkDataset

Dim pNQ As INetworkQuery
Set pNQ = pND

Dim pEnumNE As IEnumNetworkElement
Set pEnumNE = pNQ.Elements(esriNETJunction)

Dim pNEdge As INetworkEdge
Set pNEdge = pNQ.CreateNetworkElement(esriNETEdge)
Dim pNEFromJunc As INetworkJunction
Set pNEFromJunc = pNQ.CreateNetworkElement(esriNETJunction)
Dim pNEToJunc As INetworkJunction
Set pNEToJunc = pNQ.CreateNetworkElement(esriNETJunction)

Dim pNE As INetworkElement
Set pNE = pEnumNE.Next

Dim pNEJunc As INetworkJunction
Set pNEJunc = pNE

Dim i As Integer
Do Until pNE Is Nothing
    Debug.Print "Junction: " & pNEJunc.EID & " is adjacent to: " & pNEJunc.EdgeCount & " junctions."
    For i = 0 To pNEJunc.EdgeCount - 1 'For each connected edge...
      pNEJunc.QueryEdge i, True, pNEdge   'Get that connected edge
      pNEdge.QueryJunctions pNEFromJunc, pNEToJunc 'Get To junction of current edge
      Debug.Print " Adjacent Junction: " & pNEToJunc.EID & " Length " & pNEdge.AttributeValueByName("Meters") 'List the adjacency
    Next
    Set pNE = pEnumNE.Next
Loop
Exit Sub
eh:
MsgBox "Error: " & Err.Description
End Sub

Re: cost matrix

FelipeLillo — Tue, 14 Sep 2010 22:34:00 GMT

a short update...I was able to fix the "Automation error"...but now I'm gettin a "type mismatch error"...

Cheers

Philip

Re: cost matrix

FelipeLillo — Wed, 15 Sep 2010 00:18:10 GMT

Thanks very much Jay.... I was able to run the code.....However, I notice you are using the Network_Junctions as vertices... my network consists of a road layer and cities_layer (points) ..the latter supposedly is my "vertex" layer. Is there a way to use my cities_ layer as vertices rather than the Network_Junctions so that the distance between cities populates the matrix??. (usually cities_layer does not match with your Junction_layer)
Regards

Philip

Re: cost matrix

JaySandhu — Wed, 15 Sep 2010 14:00:19 GMT

You can make another point source be part of your network dataset. So you could include the cities to be part of th network. Then change the code to only look at junctions of type cities.
However, I am not sure how you will get length to the next city with the code I sent as the cities may not be linked to other cities with one to one edges. In fact, your post has again made it un-clear what you are trying to achieve. It looks like all you need is shortest distance between SOME set of cities. How do you determine what cities are connected to a given city?

Jay Sandhu

Re: cost matrix

FelipeLillo — Wed, 15 Sep 2010 21:27:13 GMT

We wanna test a new shortest path algorithm so no optimization is desired at this stage. I'm just using ArcGIS to extract the adjencecy matrix from a real network.... I have a shapeline which represents a road system ...this is built with small polylines ...I additionally have another shapefile (over 2000 points) with represents cities .

Cities are not connected by just one polyline..... many small pieces make the connection among cities. So to get the edge_length between two cities (if they are connected) we have to sum all the small pieces (unless we have a way to merge them into one long polyline)... You are right....the real question is how to find out what cities are connected to a given city.

My idea is to extend your code to firstly identify cities (intead of junctions) and next try to compute adjancency and distance....somehow I'll have to figure out how to keep tracking of the shape_lengh in the road_system.

Any help will be very appreciated.

Philip

Re: cost matrix

JaySandhu — Thu, 16 Sep 2010 13:46:52 GMT

Knowing which city is connected to which city is the key. Without it you can not generate the information. As far as I am concerned, the shortest path between two cities gives you the summed up cost of the links making up the path between the cities. So you can simply use OD for that AND if you want one shape that combines all the shapes making the path, use the Closest Facility Solver. It is same as OD but also returns back the true shape of the path that connects two locations. Hint: You can run CF between all cities and export the resulting paths to a new Feature class and then make network dataset from it.

BTW there is also a GP tool in Network Analyst toolset called DissolveNetwork that will remove all possible two valent junctions from a network dataset (by merging adjacent edges). Perhaps that can be used to simplyfy your network. More info here:
http://help.arcgis.com/en/arcgisdesktop/10.0/help/index.html#/Dissolve_Network/00480000000w000000/

Regards,
Jay Sandhu

Re: cost matrix

FelipeLillo — Sat, 25 Dec 2010 05:14:17 GMT

Hi there,

The code to compute the adjencecy matrix works very good...is there any way to compute the junctions coordinates (X,Y) through this code???

Thanks

Philip

Re: cost matrix

JaySandhu — Tue, 28 Dec 2010 16:20:53 GMT

You can get the x,y points of the junctions by querying the from/to junctions. For example, you can:

dim pFromPoint as IPoint
set pFromPoint = new Point

and then inside the loop after the QueryJunction call:

pNEFromJunc.QueryPoint pFromPoint

and now you can access the coordinates:

debug.print pFromPoint.X
debug.print pFromPoint.Y

repeat the above for the pNEToJunc

Hope that is what you wanted.
Regards,
Jay Sandhu