topic Re: Navigating by address bar in ArcGIS API for Flex Questions

Navigating by address bar

LisaStevens — Mon, 27 Sep 2010 10:28:36 GMT

Hi there,

Possibly a stupid questions but I wondered if there was a way to open up flexviewer at a particular lat/long using the address bar? i.e. I have a database that I'd like the user to click on a hyperlink which opens up at the correct address.

Is this possible?

Thanks!

Re: Navigating by address bar

JoshCalhoun1 — Mon, 27 Sep 2010 12:14:32 GMT

Do you mean you want your users to click on a record in a datagrid?

Re: Navigating by address bar

LisaStevens — Mon, 27 Sep 2010 12:19:17 GMT

I would like a field in our access database to contain a hyperlink that has co-ordinates in which in turn opens up a new webpage to the flexveiwer

Re: Navigating by address bar

Drew — Mon, 27 Sep 2010 14:06:50 GMT

I would like a field in our access database to contain a hyperlink that has co-ordinates in which in turn opens up a new webpage to the flexveiwer

There are a lot of examples on how to do this on both Google and in the ESRI forums.
I would do some digging around and see what you can find, it�??s very easy to do.

Google results:
http://www.google.ca/search?hl=&q=flex+url+parameters&sourceid=navclient-ff&rlz=1B3GGGL_enUS357US357&ie=UTF-8&aq=0&oq=Flex+URl+Par

Simple Demo On passing URL parameters in Flex:
http://www.abdulqabiz.com/files/test/QueryStringSample.html?myName=Abdul&myHomeTown=Bangalore

Demos Source:
http://www.abdulqabiz.com/blog/archives/2006/03/06/how-to-get-url-query-string-variables-within-flex-application/

Re: Navigating by address bar

RobertScheitlin__GISP — Sat, 11 Dec 2021 10:46:07 GMT

Lisa,

Here is some code to do this in FlexViewer 2.1 Just replace the existing function in MapManager.mxml with this one.

//map load complete
            private function mapLoadComplete(event:MapEvent):void
            {
    try
    {
     if (ExternalInterface.available)
     {
      var result:URLVariables = new URLVariables();
      var urlSubstring:String = ExternalInterface.call("window.location.search.substring", 1);    
      if (urlSubstring && urlSubstring.length > 0 && urlSubstring != "debug=true")
      {
       result.decode(urlSubstring);
       // Parse URL
       var xExt:String;
       var xUrlParam:String;
       var yLat:String;
       var xLon:String;
       var mScale:String;
       if (result["EXT"])
        xExt = result.EXT;
       
       if (result["LAT"])
        yLat = result.LAT;
       if (result["LON"])
        xLon = result.LON;
       if (result["SCALE"])
        mScale = result.SCALE;
       
       if(!yLat == "" && !xLon == "")
       {
        var spatRef:SpatialReference = new SpatialReference(4326);
        var cPoint:MapPoint = new MapPoint(parseFloat(xLon), parseFloat(yLat),spatRef);
        if(!mScale==""){
         map.scale = parseInt(mScale);
        }else{
         map.scale = 20000;
        }
        if (map.spatialReference.wkid != 4326)
        {
         map.cursorManager.setBusyCursor();
         var geomServ:GeometryService = new GeometryService("http://sampleserver3.arcgisonline.com/ArcGIS/rest/services/Geometry/GeometryServer");
         geomServ.addEventListener(GeometryServiceEvent.PROJECT_COMPLETE,pResult);
         geomServ.addEventListener(FaultEvent.FAULT,pFault);
         geomServ.project([cPoint],map.spatialReference);
         function pResult(event:GeometryServiceEvent):void{
          var pt:MapPoint = (event.result as Array)[0]as MapPoint;
          map.centerAt(pt);
          map.cursorManager.removeBusyCursor();
         }
         function pFault(err:Object):void{
          map.cursorManager.removeBusyCursor();
         }
        } else{
         map.centerAt(cPoint);
        }
       }
       
       if (!xExt == ""){
        var extArray:Array = xExt.split(",");
        var extent:Extent = new Extent(Number(extArray[0]), Number(extArray[1]), Number(extArray[2]), Number(extArray[3]),map.spatialReference);
        map.extent = extent;
       }
      }
     }
    }
    catch (error:Error){}
            }

And add these imports to the MapManager.mxml too.

import com.esri.ags.events.GeometryServiceEvent;
import com.esri.ags.geometry.MapPoint;
import com.esri.ags.tasks.GeometryService;
import com.esri.ags.geometry.Geometry;

And feed it a url like this
?LON=-111.88376501599998&LAT=40.75807050000003&SCALE=10000