hide the navigation bar in flex Application

lifeEsri — Thu, 16 May 2013 19:31:32 GMT

hi
how to hide the navigation bar in flex Application
some one help me please 🙂

Re: hide the navigation bar in flex Application

RobertScheitlin__GISP — Thu, 16 May 2013 19:53:30 GMT

life Esri,

Do you mean the Maps ZoomSlider?

map.zoomSliderVisible = false;

Re: hide the navigation bar in flex Application

lifeEsri — Thu, 16 May 2013 20:10:32 GMT

i mean this :==>

[ATTACH=CONFIG]24394[/ATTACH]

Re: hide the navigation bar in flex Application

RobertScheitlin__GISP — Thu, 16 May 2013 20:20:16 GMT

life Esri,

That is part of the browser not the Flex App... For questions that do not have to do with Flex you would be better off using a Google Search "hide browser address bar".

Re: hide the navigation bar in flex Application

IvanBespalov — Fri, 10 Dec 2021 20:46:26 GMT

As 1 of possible solution - U can play flash in full screen,
but with some restrictions, such as no ability to use keyboard in full screen mode...

<?xml version="1.0" encoding="utf-8"?>
<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009"
      xmlns:s="library://ns.adobe.com/flex/spark"
      xmlns:esri="http://www.esri.com/2008/ags"
      pageTitle="World Topographic Map">

 <!--
 ESRI dev. team sample - http://resources.arcgis.com/en/help/flex-api/samples/01nq/01nq00000044000000.htm
 -->
  
 <fx:Script>
  <![CDATA[
   protected function onFullScreenButtonClick(event:MouseEvent):void
   {
    if (stage.displayState == StageDisplayState.NORMAL)
    {
     stage.displayState = StageDisplayState.FULL_SCREEN;
    }
    else
    {
     stage.displayState = StageDisplayState.NORMAL;
    }
   }
  ]]>
 </fx:Script>
 
 <s:layout>
  <s:VerticalLayout horizontalAlign="center"
        paddingTop="10"
        gap="10"/>
 </s:layout>
 
 <fx:Declarations>
  <esri:Extent id="initialExtent"
      xmin="-13635000" ymin="4541000" xmax="-13625000" ymax="4547000">
   <esri:SpatialReference wkid="102100"/>
  </esri:Extent>
 </fx:Declarations>
 
 <s:Button id="btnFullScreen" 
     icon="http://s.xanga.com/images/settings/icon_fullscreen.gif"
     label="Toggle fullscreen"
     click="onFullScreenButtonClick(event)"/>
 
 <esri:Map extent="{initialExtent}">
  <esri:ArcGISTiledMapServiceLayer url="http://server.arcgisonline.com/ArcGIS/rest/services/World_Topo_Map/MapServer"/>
 </esri:Map>
 
</s:Application>

Re: hide the navigation bar in flex Application

RobertScheitlin__GISP — Fri, 10 Dec 2021 20:46:29 GMT

Ivan,

As 1 of possible solution - U can play flash in full screen,
but with some restrictions, such as no ability to use keyboard in full screen mode...

Actually that has changed in the Flash Player 11.3 and greater.

Here is the updated example Code:

<?xml version="1.0" encoding="utf-8"?>
<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009"
               xmlns:s="library://ns.adobe.com/flex/spark"
               xmlns:esri="http://www.esri.com/2008/ags"
               pageTitle="World Topographic Map"
               creationComplete="init()">
    
    <!--
    ESRI dev. team sample - http://resources.arcgis.com/en/help/flex-api/samples/01nq/01nq00000044000000.htm
    -->
    
    <fx:Script>
        <=!=[=C=D=A=T=A=[
            import com.esri.ags.geometry.MapPoint;
            
            import mx.controls.Alert;
            import mx.core.FlexGlobals;
            import mx.events.CloseEvent;
            import mx.utils.URLUtil;
            
            private var extCenter:MapPoint;
            
            protected function onFullScreenButtonClick(event:MouseEvent):void
            {
                if(flashVersion.major == 11 && flashVersion.minor >= 3){
                    var bUrl:String;
                    if(FlexGlobals.topLevelApplication.url.indexOf("file")>-1){
                        bUrl = "local";
                    }else{
                        bUrl = URLUtil.getServerName(FlexGlobals.topLevelApplication.url);
                    }
                    Alert.show("You are about to switch to full screen mode. You must click allow " +
                        "when you see an overlay that says '" + bUrl + "' is now full screen. Press esc to exit. " +
                        "You must click allow to enable keyboard interaction. " +
                        "Do you want to switch full screen mode?", "Warning", Alert.YES|Alert.NO, null, 
                        alertClickHandler, null, Alert.YES);
                }else{
                    /* If not in full screen mode, ask if they want to switch to full screen mode. */
                    Alert.show("You are about to switch to full screen mode, that limits your interaction " +
                        "with the map in a couple of ways. You can not enter text into widgets like " +
                        "the parcel search widget or other widgets when you are in full screen mode. " +
                        "Certain keyboard shortcuts will not work in full screen mode also. " +
                        "Do you want to switch full screen mode?", "Warning", Alert.YES|Alert.NO, null, 
                        alertClickHandler, null, Alert.YES);
                }
            }
            
            private var flashVersion:Object = new Object();// Object to hold the Flash version details
            
            protected function getPlayerVersion():void {
                var versionNumber:String = Capabilities.version;// Get the whole version string
                var versionArray:Array = versionNumber.split(",");// Split it up
                var length:Number = versionArray.length;
                var osPlusVersion:Array = versionArray[0].split(" ");// The main version contains the OS (e.g. WIN), so we split that off as well.
                // Populate the version object (the OS is a string, others are numbers):
                flashVersion["os"] = osPlusVersion[0];
                flashVersion["major"] = parseInt(osPlusVersion[1]);
                flashVersion["minor"] = parseInt(versionArray[1]);
                flashVersion["build"] = parseInt(versionArray[2]);
            }
            
            protected function alertClickHandler(event:CloseEvent):void
            {
                if (event.detail==Alert.YES){
                    extCenter = map.extent.center;
                    if(flashVersion.major == 11 && flashVersion.minor >= 3){
                        systemManager.stage.displayState = StageDisplayState.FULL_SCREEN_INTERACTIVE
                    }else{
                        systemManager.stage.displayState = StageDisplayState.FULL_SCREEN;
                    }
                    
                    var timer:Timer = new Timer(500, 1);
                    timer.addEventListener(TimerEvent.TIMER_COMPLETE, timerComplete);
                    timer.start();
                    
                    function timerComplete(evt:TimerEvent):void{
                        map.centerAt(extCenter);
                    }
                }
            }
            
            protected function exitFullScreen(evt:FullScreenEvent):void
            {
                if(!evt.fullScreen){
                    var timer:Timer = new Timer(500, 1);
                    timer.addEventListener(TimerEvent.TIMER_COMPLETE, timerComplete);
                    timer.start();
                    
                    function timerComplete(evt:TimerEvent):void{
                        map.centerAt(extCenter);
                    }
                }
            }
            
            protected function init():void 
            {
                systemManager.stage.addEventListener(FullScreenEvent.FULL_SCREEN, exitFullScreen);
                getPlayerVersion();
            }
        ]=]=>
    </fx:Script>
    
    <s:layout>
        <s:VerticalLayout horizontalAlign="center"
                          paddingTop="10"
                          gap="10"/>
    </s:layout>
    
    <fx:Declarations>
        <esri:Extent id="initialExtent"
                     xmin="-13635000" ymin="4541000" xmax="-13625000" ymax="4547000">
            <esri:SpatialReference wkid="102100"/>
        </esri:Extent>
    </fx:Declarations>
    
    <s:Button id="btnFullScreen" 
              icon="http://s.xanga.com/images/settings/icon_fullscreen.gif"
              label="Toggle fullscreen"
              click="onFullScreenButtonClick(event)"/>
    
    <esri:Map extent="{initialExtent}" id="map">
        <esri:ArcGISTiledMapServiceLayer url="http://server.arcgisonline.com/ArcGIS/rest/services/World_Topo_Map/MapServer"/>
    </esri:Map>
    
</s:Application>

Here is the changes that have to be made to the index.template.html. See attached

//Add 
params.allowFullScreenInteractive = "true";
//Add
<param name="allowScriptAccess" value="sameDomain" />

topic Re: hide the navigation bar in flex Application in ArcGIS API for Flex Questions

hide the navigation bar in flex Application

Re: hide the navigation bar in flex Application

Re: hide the navigation bar in flex Application

Re: hide the navigation bar in flex Application

Re: hide the navigation bar in flex Application

Re: hide the navigation bar in flex Application